在窗體中添加如下方法：
       第一個方法是 AutoCompleteKeyUp，它將組合框和 KeyEventArgs 對象作為參數(shù)，需要在組合框的 KeyUp 事件中調(diào)用此方法；它全根據(jù)用戶輸入的內(nèi)容選擇最接近的內(nèi)容；
       第二個方法是 AutoCompleteLeave，在激活組合框的 Leave 事件時調(diào)用，此方法僅提取用戶最終選擇的內(nèi)容，按照組合框中的每個匹配內(nèi)容修改其大小寫。
代碼如下：
    Private Sub AutoCompleteKeyUp(ByVal Combo As ComboBox, ByVal e As KeyEventArgs)
        Dim strTyped As String
        Dim intFoundIndex As Integer
        Dim objFoundItem As Object
        Dim strFoundText As String
        Dim strAppendText As String
        '忽略特殊鍵
        Select Case e.KeyCode
            Case Keys.Back, Keys.Left, Keys.Right, Keys.Up, Keys.Down, Keys.Delete, Keys.CapsLock
                Return
        End Select
        '在查詢列表中找到
        strTyped = Combo.Text
        intFoundIndex = Combo.FindString(strTyped)
        If intFoundIndex >= 0 Then
            objFoundItem = Combo.Items(intFoundIndex)
            strFoundText = Combo.GetItemText(objFoundItem)
            strAppendText = strFoundText.Substring(strTyped.Length)
            Combo.Text = strTyped & strAppendText
            Combo.SelectionStart = strTyped.Length
            Combo.SelectionLength = strAppendText.Length
        End If
    End Sub
 
    Private Sub AutoCompleteLeave(ByVal Combo As ComboBox)
        Dim intFoundIndex As Integer
        intFoundIndex = Combo.FindStringExact(Combo.Text)
        Combo.SelectedIndex = -1
        Combo.SelectedIndex = intFoundIndex
End Sub
 
    Private Sub ComboBox1_KeyUp(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles ComboBox1.KeyUp
        AutoCompleteKeyUp(ComboBox1, e)
    End Sub
 
    Private Sub ComboBox1_Leave(ByVal sender As Object, ByVal e As System.EventArgs) Handles ComboBox1.Leave
        AutoCompleteLeave(ComboBox1)
    End Sub