TeeChart Pro ActiveX教程（十九）：TeeChart工具集（六）

---

下載TeeChart Pro ActiveX最新版本

本文將續(xù)講工具集中的頁(yè)碼工具、餅圖切片工具、旋轉(zhuǎn)工具和系列動(dòng)畫工具。

一、頁(yè)碼工具

頁(yè)碼工具顯示一個(gè)完全可配置的文本框，其中包含所選的頁(yè)碼編號(hào)系統(tǒng)。

設(shè)計(jì)時(shí)：

頁(yè)碼工具的文本及其所在的框都可以完全配置。“Options”選項(xiàng)卡允許您輸入所需的文本，并指定其對(duì)齊方式以及鼠標(biāo)懸停在工具上時(shí)顯示的光標(biāo)類型。 “Position”選項(xiàng)卡指定頁(yè)碼工具的默認(rèn)位置或自定義位置。 “Callout”選項(xiàng)卡定義“Page Tool”的“Callout”對(duì)象，該對(duì)象用于從注釋中繪制線到圖表中的任何位置。“Format”選項(xiàng)卡配置文本框，允許您更改其顏色，框架，圖案，斜角，大小，圓度和透明度。 “Text”選項(xiàng)卡可以設(shè)置文本字體，顏色，輪廓和間距以及文本陰影的顏色和大小。 “Gradient”選項(xiàng)卡配置文本框漸變的屬性，而“Shadow”選項(xiàng)卡配置文本框陰影的屬性。

運(yùn)行時(shí)：

With TChart1
    .Tools.Add tcPageNumber
    With .Tools.Items(0)
        .Active = True
        .asPageNum.Position = ppRightTop
        .asPageNum.Shape.Gradient.Visible = True
    End With
End With

二、餅圖切片工具

“Pie Slices Tool/餅圖切片工具”通過在其周圍繪制邊框或通過將其從餅圖系列的其余部分展開來(lái)突出顯示鼠標(biāo)下的餅圖切片。

設(shè)計(jì)時(shí)：

餅圖切片工具必須與特定的Pie系列相關(guān)聯(lián)才能顯示。樣式指定工具是否將焦點(diǎn)放在鼠標(biāo)懸停的餅圖上，或者是否會(huì)將其從其余部分中分離出來(lái)。Border指定圍繞焦點(diǎn)餅圖繪制的邊框的筆特征。

運(yùn)行時(shí)：

With TChart1
    .Aspect.View3D = False
    .AddSeries scPie
    .Series(0).asPie.Circled = False
    .Series(0).FillSampleValues 6
    
    .Tools.Add tcPie
    With .Tools.Items(0).asPie
        .Series = TChart1.Series(0)
        .Style = ptFocus
    End With
End With

三、旋轉(zhuǎn)工具

將鼠標(biāo)拖到圖表上時(shí)，“Rotate/旋轉(zhuǎn)”工具會(huì)更改圖表的標(biāo)高和旋轉(zhuǎn)。

設(shè)計(jì)時(shí)：

旋轉(zhuǎn)工具設(shè)計(jì)時(shí)可配置屬性包括Inverted在旋轉(zhuǎn)圖表時(shí)反轉(zhuǎn)鼠標(biāo)移動(dòng)的效果，Style指定圖表是旋轉(zhuǎn)、標(biāo)高還是兩者都有，Button指定用于旋轉(zhuǎn)圖表的鼠標(biāo)按鈕，而Outline配置圖表輪廓可以是在移動(dòng)指定的鼠標(biāo)按鈕時(shí)繪制。

運(yùn)行時(shí)：

With TChart1
    .Tools.Add tcRotate
    With .Tools.Items(0)
        .Active = True
        .asRotate.Button = mbRight
    End With
End With

四、系列動(dòng)畫工具

系列動(dòng)畫工具執(zhí)行系列點(diǎn)的增長(zhǎng)動(dòng)畫。

設(shè)計(jì)時(shí)：

系列動(dòng)畫工具必須與特定系列相關(guān)聯(lián)。 步驟定義系列動(dòng)畫工具所采用的動(dòng)畫步數(shù)，“開始時(shí)最小值/Start at Min value”將從minium Series YValue開始動(dòng)畫，而“Start value/開始值”指定“Start at Min value/最小值時(shí)開始”值設(shè)置為false時(shí)的起始值。 繪制每個(gè)將以n個(gè)點(diǎn)的組繪制系列。

請(qǐng)查看以下系列動(dòng)畫工具的工作示例：

運(yùn)行時(shí)：

Private Sub Command1_Click()
On Error Resume Next
HScroll1.Enabled = False
Command1.Enabled = False
TChart1.Tools.Items(0).asSeriesAnimation.Execute
HScroll1.Enabled = True
Command1.Enabled = True
End Sub
 
Private Sub Command2_Click()
TChart1.Tools.Items(0).ShowEditor
HScroll1.Value = TChart1.Tools.Items(0).asSeriesAnimation.Steps
End Sub
 
Private Sub Check1_Click()
  If Check1.Value = 1 Then
     TChart1.Tools.Items(0).asSeriesAnimation.DrawEvery = 1
  Else
     TChart1.Tools.Items(0).asSeriesAnimation.DrawEvery = 0
  End If
End Sub
 
Private Sub Form_Load()
TChart1.AddSeries scBar
TChart1.Series(0).ColorEachPoint = True
TChart1.Tools.Add tcSeriesAnimation
HScroll1.Min = 1
HScroll1.Max = 255
HScroll1.Value = 100

TChart1.Series(0).FillSampleValues 6
TChart1.Legend.Visible = False
TChart1.Series(0).ValueFormat = "000"
TChart1.Tools.Items(0).asSeriesAnimation.Series = TChart1.Series(0)
TChart1.Tools.Items(0).asSeriesAnimation.StartAtMin = False
End Sub
 
Private Sub HScroll1_Change()
TChart1.Tools.Items(0).asSeriesAnimation.Steps = HScroll1.Value
Label2.Caption = HScroll1.Value
End Sub
 
Private Sub HScroll1_Scroll()
Label2.Caption = HScroll1.Value
End Sub
 
Private Sub TChart1_OnSeriesAnimationToolStep(ByVal Tool As Long, ByVal Step As Long)
If Tool = 0 Then
    With TChart1
        .Series(0).PointColor(0) = RGB(255 - Step, Step, Step)
        .Series(0).PointColor(1) = RGB(Step, 255 - Step, Step)
        .Series(0).PointColor(2) = RGB(Step, Step, 255 - Step)
        .Series(0).PointColor(3) = RGB(255 - Step, 255 - Step, Step)
        .Series(0).PointColor(4) = RGB(Step, 255 - Step, 255 - Step)
        .Series(0).PointColor(5) = RGB(255 - Step, Step, 255 - Step)
    End With
End If
End Sub